Tadpole Survival

A common problem in quantitative genetics is the estimation of the variation in the various genetic and environmental components that contribute to the variation in a trait. The most important component is usually the additive component, which is related to the strength of natural selection. This variation can be estimated from controlled mating experiments. Traditionally, the additive variance is esimated from the Male effect but here we are able to include the contributions from all of the levels of the experiment, which is clearly a more efficient use of the data

We analyse a part of a data set on survival of tadpoles, which used a "North Carolina I" design. 30 males were used in the experiment, and each one was mated to two females. The females were only mated to a single male. The eggs from each cross were split up into groups of between 15 and 51 eggs, and placed in several treatments and blocks. The data here comes from the high pH treatment, and two of the blocks (for simplicity, the block effect is not modelled here). The trait of interest is whether a tadpole survives to Gosner Growth Stage 25 (whatever that is). We also use the average egg size for a female as a covariate. The number of tadpoles in a batch of size N _i that survive to GS25 is n _i . We then use mixed model logistic regression:

   n _i ~ Bin(N _i , p _i )

   logit(p _i ) ~N( m _i , s _e ) where m _i = m ₀ + (a _s + a _d )/2 + b _d , + d _d /4
   
    a _s , a _d ~ N(0, v _Add )
    b _d ~ N(0, v _Mat )
    d _d ~ N(0, vD _om )
      
where m ₀ is the overall mean, a _s and a _d are the sire's and dam's breeding values, b _d is the maternal effect and d _d is the dominance effect. s _e is the residual variance, which is made up of contributions from the additive and dominance variation, due to segregation. Rather than writing this as the sum of the variance contributions, it is quicker to simulate the errors directly, i.e. write

   m _i = m ₀ + (a _s + a _d )/2 + b _d , + d _d /4 + e ^a _i /2 ^1/2 + (3/4) ^1/2 e ^d _i
   
where e _i ^a ~ N (0, v _Add ) and + e _i ^d ~ N (0, v _Dom ). Now s _e is v _{Env W} , the within environment variance.

Because of the design of the experiemnt, there are identifiability problems with v _Dom , v _{Env W} and v _Mat . However, our main interest is in the proportion of the total variance explained by v _Add , i.e. h ² = v _add /(v _add +v _dom +v _Mat +v _{Env W} )

v _{Add ,} v _{Dom ,} v _Mat and v _{Env W} are all given uninformative uniform priors with an upper limit that is larger than possible (i.e. much larger than the variance of the data). This gives better frequentist properties (e.g. O'Hara & Merilä, in press) than the inverse gamma distribution.


Model

model;
{
   for(i in 1 : N)   {
      add.err[i] ~ dnorm(0, TauAdd)
      dom.err[i] ~ dnorm(0, TauDom)
      error[i] ~ dnorm( 0.0,TauEnvW)
         
      logit(pp[i]) <- Mu0 + (alphaMale[Male[i]] + alphaFemale[Male[i], Female[i]])/2 + maternal[Male[i], Female[i]] +
                              Delta[Male[i], Female[i]]/2 + add.err[i]/sqrt(2) + sqrt(3/4)*dom.err[i] + error[i]
      Alive[i] ~ dbin(pp[i],Total[i])
   }
   for(m in 1 : MaleTot) {
      alphaMale[m] ~ dnorm( 0,TauAdd)
      for(f in 1:2) {   
         alphaFemale[m,f] ~ dnorm( 0,TauAdd)
         maternal[m,f] ~ dnorm( 0,TauMat)
         Delta[m,f] ~ dnorm( 0,TauDom)
       }
   }
    Mu0 ~ dnorm( 0,0.1)

    VarAdd ~ dunif( 0,1000)
    VarDom ~ dunif( 0,1000)
   VarEnvW ~ dunif( 0,1000)
   VarMat ~ dunif( 0,1000)
   
   TauAdd <- 1/VarAdd
   TauDom <- 1/VarDom
   TauEnvW <- 1/VarEnvW
   TauMat <- 1/VarMat

   TotVar <- VarAdd + VarDom + VarEnvW + VarMat
    Heritability <- 1/ (TauAdd*TotVar)
}



Data

list(N=119, MaleTot=30,
Male=c( 1,1,2,2,3,3,4,4,5,5,6,6,7,7,8,8,9,9,10,10,11,11,12,12,13,13,14,14,15,15,16,16,17,17,18,18,19,19,20,20,21,21,22,22,23,23,24,24,25,25,26,26,27,27,28,28,29,29,30,30,1,1,2,2,3,3,4,4,5,6,6,7,7,8,8,9,9,10,10,11,11,12,12,13,13,14,14,15,15,16,16,17,17,18,18,19,19,20,20,21,21,22,22,23,23,24,24,25,25,26,26,27,27,28,28,29,29,30,30),
Female=c( 1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2,1,2),
Alive=c( 14,2,8,15,17,23,22,28,5,16,21,20,18,22,22,8,17,32,4,7,9,18,31,9,20,12,9,10,27,21,16,22,13,24,22,17,17,14,6,23,25,18,19,29,10,1,19,25,29,21,28,21,20,28,21,23,21,23,16,11,6,0,7,13,18,22,23,20,19,23,23,16,16,26,13,23,28,0,11,13,23,27,13,24,15,13,11,22,25,19,31,13,25,23,22,19,17,1,24,22,24,26,24,12,5,21,29,24,16,26,28,18,23,22,20,19,22,14,23),
Total=c( 34,25,24,23,25,23,23,29,28,21,26,22,33,24,25,24,20,32,23,24,24,24,31,23,20,26,24,29,28,21,20,23,21,29,23,18,18,26,23,24,26,20,26,30,27,26,20,29,29,24,29,23,24,28,21,23,23,28,25,22,18,26,24,17,26,23,32,22,24,23,24,24,21,26,23,24,28,27,24,24,23,28,22,25,25,23,24,22,25,21,33,19,26,26,24,21,21,26,24,22,24,26,25,22,26,22,30,25,18,27,28,21,23,23,20,22,24,20,26) )


Inits
list(VarAdd =1, VarDom =1, VarEnvW =1, VarMat =1)

Results

Two chains were run, and after a burn-in of 1000 iterations, a further 10000 iterations per chain were run, to give 2x10000 samples. This took 130 seconds on a 2GHz processor.
          mean   sd   MC_error   val2.5pc   median   val97.5pc   start   sample
   Heritability   0.1295   0.1086   0.006233   0.009633   0.1043   0.4065   1001   20000
   Mu0   1.818   0.2898   0.01345   1.27   1.806   2.427   1001   20000
   VarAdd   0.5855   0.4927   0.02826   0.04388   0.4738   1.837   1001   20000
   VarDom   0.3026   0.2525   0.0138   0.02443   0.241   0.9459   1001   20000
   VarEnvW   0.2269   0.1914   0.009831   0.01516   0.1799   0.7208   1001   20000
   VarMat   3.544   1.045   0.03034   1.8   3.445   5.907   1001   20000

The posterior for the heritability is low compared to the typical value of around 0.2. The Maternal component has the largest variance, suggesting that there is a large variation in maternal effect on early survival.

References

Lynch M, Walsh B (1998). Genetics and analysis of quantitative traits . Sinauer Ass., Inc.

O'Hara, R.B. and Merilä, J. Bias and precision in Q _ST estimates: problems and some solutions. Genetics , in press.

Pakkasmaa, S., Merilä J., O'Hara R.B., 2003. Genetic and maternal effect influences on viability of common frog tadpoles under different environmental conditions. Heredity , 91 : 117-124.